In my Fortran 95 program I have the following two types:

In module ProfileTyp, public type:

TYPE :: TProfileData
   REAL (DP) :: Cv = 0.0_DP, CC = 0.0_DP, NominalClAp = 0.0_DP
END TYPE TProfileData

and in module AspDatTyp (which uses ProfileTyp):

TYPE :: TAspData
   TYPE (TProfileData) :: Profiles (2, NO_OF_WAVELENGTHS)
   INTEGER (DI) :: NType = 0
   ! more components
END TYPE TAspData

where DP, DI and NO_OF_WAVELENGTHS are INTEGER PARAMETERS available via
USE association of other modules (not shown here).

        I'd like to use Fortran 2003 extensible types and have TYPE TAspData
EXTEND TYPE TProfileData. Is there any way I can do this? (This wouldn't
be a problem if Profiles weren't an array.) Perhaps someone with some
good experience with C++ can help. Or is this a case where I have a "has
a" relationship, not an "is a" one?

Hello Norman,

 Since most compilers support TR15581, you could shift the array
 property to the components of TProfileData and extend from there:

TYPE :: TProfileData
   REAL (DP), allocatable, dimension(:,:) :: Cv, CC, NominalClAp
END TYPE TProfileData
TYPE, extends(TProfileData) :: TAspData
  integer(DI) :: NType = 0
  :
END TYPE

 The allocation itself would need to take care of initialization.
 More elegantly, type parameters could be used:

 TYPE :: TProfileData(n,m)
    integer, len :: n, m
    real(DP) :: Cv(n,m) ,....
 END TYPE

  but to my knowledge no compiler supports this feature yet.
  Both solutions have the disadvantage that all code involving
  objects of the base type needs to be changed
  (foo(k,i)%cv --> foo%cv(k,i) etc.)

  If this is too much work,

 TYPE :: TProfileDataArray
     type(TProfileData) :: Profiles (2, NO_OF_WAVELENGTHS)
  END TYPE

  could be introduced as a base type, but then you still need to
  write wrappers for all methods operating on arrays of type
  TProfileData.

Regards